Документация QSP

СайтФорум

• В QSP нет таких разделителей команд, как ';' в Паскале. Команды разделяются переносом строки или знаком '&':

  i=0
  j=0

  равнозначно

  i=0 & j=0

• Пробелы и символы табуляции в начале строки не влияют на выполнение кода, зато позволяют сделать его более читаемым:

  if яблоки=0 :
      ADDOBJ 'Яблоко'
      яблоки=1
  end
  

• Иногда бывает удобно разбить строку на несколько. Чтобы следующая строка считалась частью текущей, нужно в конце строки дописать ' _' (пробел и символ подчёркивания):

  if a<5 and n-b>4+5+h/7*2 or t=4: p 'TTTTTTTTT' & cla & $f='Text Variable' & goto 'FFFF'
  

  равнозначно

  if a<5 and n-b> _
      4+5+h/7*2 or  _
      t=4: p 'TTTTTTTTT' _
    & cla & $f='Text Variable' _
    & goto 'FFFF'
  

  • Группа строк, разделённых " _", считается одной строкой (сообщения об ошибках также выводятся с учётом того, что это одна строка).
  • После OR стоит не один, а два пробела - один пробел расходуется на " _", получилось бы "ort=4" вмето "or t=4".
    • Исправлено: в более новых версиях (Quest Navigator, возможно даже в AeorQSP) пробел сохраняется.

Для пояснений в коде удобно использовать комментарии, которые игнорируются интерпретатором (плеером):

  !Однострочный комментарий
  яблоки = 0
!'Многострочный
комментарий'
яблоки = 1
  сыр = 5 &  ! А здесь"комментарий начинается
  в той же строке, но" заканчивается 'сильно
  позже'. Во всём виноваты {кавычки и скобки
  }Кстати:
  яблоки=0
 !'Комментарии рекомендуется писать всё-таки
в отдельных строках, а не как с "сыром"'

Примечание: при выводе ошибок многострочные комментарии считаются интерпретатором за одну строку.

Оператор - ключевое слово, выполняющее какое-либо действие. Оператор может иметь аргументы (параметры), которые задаются выражениями. Операторы не возвращают результат выполнения.

!'Общий вид вызова оператора
    имя_оператора аргумент1, аргумент2, ...
или
    имя_оператора (аргумент1, аргумент2, ...)
'
!Примеры вызовов операторов:
ADDOBJ 'ключ','pics/key.png'
ADDOBJ ('ключ','pics/key.png')
PL ('текст')
CLEAR()

Функция - почти тоже, что и оператор, но функция возвращает значение. При количестве аргументов более одного скобки обязательны.

!Примеры вызовов функций:
X=MAX(1,2,4)
A=RAND 4
B=COUNTOBJ
pl str(43)
pl $str(43)
!Последние два выражения эквивалентны

Примечание: при использовании функций возвращающих текстовое значение настоятельно рекомендуется приписывать перед именем функции символ '$' для улучшения читаемости кода.

Примечание: Максимальное количество аргументов равно 10

Это те функции, которые я пока никуда не пристроил.

• QSPVER - возвращает версию библиотеки интерпретатора в формате "X.Y.Z".
• CURLOC - возвращает название текущей локации.
• Математические функции
  • RAND([#выр1],[#выр2]) - возвращает случайное число между числами [#выр] и [#выр2].
    • Параметр [#выр2] может отсутствовать, при этом он принимается равным 0.
      • В более поздних версиях библиотеки [#выр2] по умолчанию принимается за 1.
    • Примеры:

      RAND(1,4) &! вернёт случайное значение от 1 до 4
      RAND(4,1) &! вернёт случайное значение от 1 до 4
      RAND(1000) &! вернёт случайное значение от 0 до 1000
      RAND 1000 &! вернёт случайное значение от 0 до 1000

  • RND - возвращает случайное значение от 1 до 1000.
  • MAX([выр1],[выр2], …) - возвращает максимальное из значений выражений-аргументов.
    • Если передан один аргумент, то считается, что указано имя массива.
    • Примеры:

      MAX(1,2,5,2,0) &! вернёт 5
      MAX(a,b,c) &! вернёт максимальное из значений переменных a,b,c
      MAX('aa','ab','zz') &! вернёт 'zz'
      MAX('a') &! вернёт максимальное из значений элементов массива "A"
      MAX('$b') &! вернёт максимальное из значений элементов массива "$B"

  • MIN([выр1],[выр2], …) - возвращает минимальное из значений выражений-аргументов.
    • Если передан один аргумент, то считается, что указано имя массива.

Вперёд: Массивы